Comment filtrer sur Excel : bonnes pratiques, formules et exemples

Créer un filtre sur Excel passe par l’apprentissage de certaines formules, qui sont ensuite déclinables selon vos besoins. Voici nos exemples pour bien utiliser cette fonction.

La fonction filtre d'Excel permet de mettre rapidement en évidence des données issues de tableaux parfois complexes ou denses. © Montage BDM

Sommaire

Sur Excel, la fonction filtre permet de filtrer une plage de données en fonction d’un ou plusieurs critères définis. Ces filtres nécessitent des formules (ou fonctions) précises, mais les modèles de base restent les mêmes à chaque fois. Les formules qu’il vous sera utile de connaître sont les suivantes :

=FILTRE(tableau;critère),
=FILTRE(tableau;(critère1)*(critère2)),
=FILTRE(tableau;(critère1)+(critère2)),
=FILTRE(tableau;critère;“si aucun résultat“).

Une fois mis en pratique, ces modèles sont simples à assimiler. Nous vous proposons 5 exemples pour tout comprendre de la fonction filtre d’Excel.

1er exemple : créer un filtre Excel pour une valeur

Le but de ce premier exemple est de filtrer les compagnies qui vendent au minimum 8 000 unités de produits parmi toutes les données du tableau de gauche et d’obtenir les résultats du filtrage dans le tableau de droite.

Excel – Fonction filtre – tableau — Voici le tableau de données que nous utiliserons tout au long de cet article. © Montage BDM

Pour mettre en place ce filtre, il faut tout d’abord se placer dans la cellule (dans notre cas, la cellule H4) qui doit accueillir le résultat du filtrage pour y rédiger la formule. Celle-ci est la suivante : =FILTRE(A4:D18;D4:D18>=8000). Comment la comprendre :

A4:D18 correspond à la plage prise en compte dans l’opération, ici l’intégralité de notre tableau.
D4:D18 correspond à la plage où doit être appliqué le critère de filtrage, c’est-à-dire nos unités de produits,
>=8000 correspond à la condition, nous ne souhaitons conserver que les compagnies qui vendent 8 000 unités ou plus.

Excel – Fonction filtre – Exemple 1 — Excel surligne sur le tableau les éléments saisis dans la formule. © Montage BDM

Il ne reste plus qu’à appuyer sur Entrée pour valider le filtre et voir les résultats s’afficher. Ici, nous avons bien un tableau constitué des compagnies qui vendent plus de 8 000 unités de produits quels qu’ils soient.

Excel – Fonction filtre – Exemple 1 bis — La formule correctement entrée, le filtre s’applique automatiquement. © Montage BDM

2e exemple : créer un filtre Excel pour un élément textuel

Dans un deuxième temps, nous souhaitons filtrer et afficher les compagnies qui vendent des pneus, peu importe où elles se trouvent dans le monde. Pour ce faire, nous allons entrer la formule suivante : =FILTRE(A4:D18;C4:C18=“Pneus“). À nouveau, voici comment la comprendre :

A4:D18 correspond à la plage prise en compte dans l’opération, ici l’intégralité de notre tableau,
C4:C18 correspond à la plage soumise à notre critère de filtrage,
=“Pneus“ correspond à notre critère.

Excel – Fonction filtre – Exemple 2 — Vous pouvez saisir manuellement, entre guillemets, l’élément qui conditionne le filtrage. © Montage BDM

Il existe une autre possibilité pour appliquer un tel filtre. Vous pouvez, plutôt que d’inscrire manuellement « Pneus » dans votre formule, sélectionner une cellule où est fait mention de votre critère. Ci-dessous, nous avons créé une liste déroulante afin d’avoir sous la main nos conditions. Nous entrons alors la formule =FILTRE(A4:D18;C4:C18=F4), la cellule F4 remplaçant la mention des pneus en toutes lettres puisque celle-ci y est inscrite.

Excel – Fonction filtre – Exemple 2 bis — Ici, la cellule F4 correspond à la mention « Pneus ». © Montage BDM

3e exemple : créer un filtre Excel en fonction de plusieurs critères

Nous voulons désormais appliquer deux conditions sur notre filtre. Dans le cas de notre exemple, il s’agit de filtrer les compagnies qui vendent 8 000 unités ou plus de pneus. Nous allons donc, toujours en cellule H4 destinée aux résultats, entrer la formule suivante : =FILTRE(A4:D18;(D4:D18>=8000)*(C4:C18=“Pneus“)). Voici sa signification :

A4:D18 correspond toujours à la plage de données à prendre en compte,
(D4:D18>=8000)*(C4:C18=“Pneus“) correspond à nos deux conditions déjà utilisées dans nos précédents exemples. Pour les mettre en corrélation, assurez-vous de les inclure toutes les deux entre parenthèses et de les séparer du signe * (astérisque ou signe multiplicateur).

Le filtre s’applique et vous montre bien les compagnies ayant vendu plus de 8 000 pneus.

Excel – Fonction filtre – Exemple 3 — Deux critères sont pris en compte ici, mais rien n’empêche d’en appliquer plus selon vos besoins. © Montage BDM

4e exemple : créer un filtre Excel en fonction d’au moins un critère

Il est également possible de filtrer un tableau de données en fonction d’au moins un critère sur plusieurs demandés. Par exemple, nous voulons, à l’issue du filtrage, toutes les compagnies européennes et toutes celles qui vendent moins de 9 000 unités de produits. La formule de filtre doit être rédigée de façon à ce qu’on obtienne toutes les compagnies d’Europe indépendamment de leur volume de vente, ainsi que toutes les compagnies du reste de la planète qui vendent un volume inférieur à 9 000. La voici : =FILTRE(A4:D18;(B4:B18=“Europe“)+(D4:D18<=9000)).

Ici, la seule différence est l’emploi du signe + pour signifier à votre filtre Excel que ces deux critères s’ajoutent de façon indépendante et ne sont pas conditionnés l’un à l’autre.

Excel – Fonction filtre – Exemple 4 — Ici, nous avons bien les compagnies européennes et celles qui vendent au moins 9000 unités. © Montage BDM

5e exemple : créer un filtre Excel avancé à double critère

Pour ce dernier exemple sur les filtres Excel, nous souhaitons obtenir rapidement la liste des compagnies qui vendent entre 8 000 et 10 000 unités de produits. Grâce aux situations décrites plus haut, nous avons toutes les connaissances pour mettre en place un tel filtre. Voici une des formules qu’il est possible d’utiliser : =FILTRE(A4:D18;(D4:D18>=8000)*(D4:D18<=10000)). Son explication est :

A4:D18 correspond au tableau de données dans son intégralité,
(D4:D18>=8000)*(D4:D18<=10000) correspond à la mise en relation de nos deux critères, dans un premier temps les valeurs situées dans la colonne D4:D18 strictement supérieures ou égales à 8 000 et dans un second temps les valeurs strictement inférieures ou égales à 10 000.

À nouveau, il est possible de se passer de la formulation complète qui inclut les signes >= en entrant les données ayant valeur de critères de filtrage dans des cellules. Ici, nos valeurs minimum et maximum ont été entrées dans les cellules F6 et F8, que nous pouvons donc utiliser dans la formule de cette manière : =FILTRE(A4:D18;(D4:D18>=F6)*(D4:D18<=F8)). Les cellules F6 et F8 viennent donc remplacer les mentions >=8000 et <=10000.

Excel – Fonction filtre – Exemple 5 — Voici les deux méthodes pour rédiger votre formule. © Montage BDM

Une dernière astuce en cas de filtrage sans résultat

Il est possible que vous mettiez en place un filtre dont aucun résultat ne ressort. Pour éviter qu’Excel affiche une erreur ou pour préciser qu’aucune donnée n’a été trouvée en rapport avec votre filtre, vous pouvez paramétrer vous-même, dans votre formule, une mention le précisant. Il suffit pour cela d’ajouter votre court texte entre guillemets à la fin de la formule.

Par exemple, nous souhaitons que notre filtre nous donne les compagnies qui vendent 13 000 unités ou plus de produits. Il n’y en a aucune, mais estimons que nous n’en savons rien. Nous allons donc entrer la formule qui convient pour notre filtre, avec un texte en cas de résultat manquant : =FILTRE(A4:D18;D4:D18>=13000;“aucun résultat“).

Excel – Fonction filtre – Astuce — Le message pré-saisi s’affiche bien dans la cellule de destination du filtre. © Montage BDM

Vous pouvez aussi décréter que le champ restera vide si aucun résultat ne ressort. Pour cela, la formule est identique, mais en n’inscrivant rien entre les guillemets. Exemple : =FILTRE(A4:D18;D4:D18>=13000;““).